Project:SPARQL/advanced

Archological categories

Where Timna Smelting sites are located

One way into the data is through the locations of archeological sites. This query does that for all the sites but could be adapted (on lines 16 remove # and choose *Qxx*) to look for other places or regions.

PREFIX wd: <https://timna-database.wikibase.cloud/entity/>
PREFIX wdt: <https://timna-database.wikibase.cloud/prop/direct/>
PREFIX p: <https://timna-database.wikibase.cloud/prop/>
PREFIX ps: <https://timna-database.wikibase.cloud/prop/statement/>
PREFIX geo: <http://www.opengis.net/ont/geosparql#>

SELECT DISTINCT ?entity ?entityLabel ?coordinate ?periodLabel (GROUP_CONCAT(DISTINCT ?categoryLabel; separator=", ") AS ?categories)
WHERE {
  ?entity wdt:P28 ?coordinate .
  ?entity wdt:P93 wd:Q115 .  # Filter for Late Bronze Age or Iron Age
  
  # Ensure the entity is a smelting site
  ?entity p:P94 ?smeltingStatement .
  ?smeltingStatement ps:P94 wd:Q89 .

  # Get all categories associated with P94
  ?entity p:P94 ?statement .
  ?statement ps:P94 ?category .
  ?category rdfs:label ?categoryLabel .
  FILTER (lang(?categoryLabel) = "en")

  ?entity rdfs:label ?entityLabel .
  FILTER (lang(?entityLabel) = "en")
  
  wd:Q115 rdfs:label ?periodLabel .
  FILTER (lang(?periodLabel) = "en")
}
GROUP BY ?entity ?entityLabel ?coordinate ?periodLabel
LIMIT 300


##defaultView:Map

Try it!

Count Archaeological categories

Show a Bar chart of all occurrences of archaeological categories

PREFIX wd: <https://timna-database.wikibase.cloud/entity/>
PREFIX wdt: <https://timna-database.wikibase.cloud/prop/direct/>
PREFIX p: <https://timna-database.wikibase.cloud/prop/>
PREFIX ps: <https://timna-database.wikibase.cloud/prop/statement/>

SELECT ?categoryLabel (COUNT(?entity) AS ?categoryCount)
WHERE {
  ?entity p:P94 ?statement .
  ?statement ps:P94 ?category .

  # Retrieve the label of the archaeological category
  ?category rdfs:label ?categoryLabel .
  FILTER (lang(?categoryLabel) = "en")

  # Retrieve the label of the item itself
  ?entity rdfs:label ?entityLabel .
  FILTER (lang(?entityLabel) = "en")

  # Exclude "N/A" category, case insensitive, ignoring any leading/trailing whitespace
  FILTER (!REGEX(STR(?categoryLabel), "^\\s*N/A\\s*$", "i"))
  
  # Filter only items whose labels start with "Site"
  FILTER (STRSTARTS(?entityLabel, "Site"))
}
GROUP BY ?categoryLabel
ORDER BY DESC(?categoryCount)

##defaultView:BarChart

Try it!